
    Filtering

Mix.install([
  {:nx_signal, "~> 0.3"},
  {:vega_lite, "~> 0.1"},
  {:kino_vega_lite, "~> 0.1"}
])
Prepare the data
fs = 16.0e3
window_duration_seconds = 100.0e-3
window_length = 2 ** ceil(:math.log2(fs * window_duration_seconds))
signal_duration_seconds = 3
signal_length = ceil(signal_duration_seconds * fs)

sin = fn freq, n ->
  Nx.sin(Nx.multiply(2 * :math.pi() * freq / fs, n))
end

half_n = Nx.iota({div(signal_length, 2)})

sin220 = sin.(220, half_n)
sin440 = sin.(440, half_n)
sin1000 = sin.(440 * 5 / 2, half_n)
sin3000 = sin.(220 * 4 / 3 * 4, half_n)

n = Nx.iota({signal_length})
t = Nx.divide(n, fs)
data = Nx.concatenate([Nx.add(sin440, sin1000), Nx.add(sin220, sin3000)])

# Data for plotting

slice = (signal_length - 3000)..(signal_length - 2750)
plot_data = %{y: Nx.to_flat_list(data[[slice]]), x: Nx.to_flat_list(t[[slice]])}
VegaLite.new(width: 600, height: 400, title: "Signal sample")
|> VegaLite.data_from_values(plot_data, only: ["x", "y"])
|> VegaLite.mark(:line)
|> VegaLite.encode_field(:x, "x", type: :quantitative)
|> VegaLite.encode_field(:y, "y", type: :quantitative)
Preparing the Filter
# Cutoff frequency in Hz
fc = 600

# Design the FIR filter coefficients using the window method
h = NxSignal.Filters.firwin(window_length, [fc], sampling_rate: fs, window: :hann)

# Separate periodic Hann window for STFT analysis
stft_window = NxSignal.Windows.hann(window_length)

hfft =
  h
  |> Nx.fft(length: window_length)
  |> Nx.abs()
  |> Nx.add(1.0e-10)

hfft_power =
  hfft
  |> Nx.log()
  |> Nx.divide(Nx.log(10))
  |> Nx.multiply(20)

f_idx = Nx.iota({window_length}) |> Nx.subtract(div(window_length, 2))

f = Nx.multiply(f_idx, fs / window_length)

plot_data = %{
  n: Enum.to_list(0..(window_length - 1)),
  h: Nx.to_flat_list(h),
  hfft:
    Nx.to_flat_list(
      Nx.take_along_axis(
        hfft_power,
        Nx.select(Nx.less(f_idx, 0), Nx.add(f_idx, window_length), f_idx)
      )
    ),
  f: Nx.to_flat_list(f)
}
VegaLite.new(
  width: 600,
  height: 400,
  title: "600 Hz Low-Pass filter (Hann window); L = 2048"
)
|> VegaLite.data_from_values(plot_data, only: ["n", "h"])
|> VegaLite.mark(:line)
|> VegaLite.encode_field(:x, "n", type: :quantitative)
|> VegaLite.encode_field(:y, "h", type: :quantitative)
VegaLite.new(
  width: 600,
  height: 400,
  title: "FFT - 600 Hz Low-Pass filter (Hann window); L = 2048"
)
|> VegaLite.data_from_values(plot_data, only: ["f", "hfft"])
|> VegaLite.mark(:line)
|> VegaLite.encode_field(:x, "f", type: :quantitative)
|> VegaLite.encode_field(:y, "hfft", type: :quantitative)
Direct Convolution
The simplest way to apply the FIR filter is to convolve the signal directly with the coefficients in the time domain.
data_filtered =
  NxSignal.Convolution.convolve(data, h, mode: :same, method: :fft)
  |> Nx.as_type(data.type)
Filtering the data
# Alternatively, we can multiply each STFT frame by the DFT of the
# filter (represented by hfft) to apply it in the frequency domain.

{z, t, f} =
  NxSignal.stft(data, stft_window, fft_length: window_length, sampling_rate: fs, scaling: :spectrum)
# Filter
z_filtered = Nx.multiply(z, hfft)

max_f =
  Nx.select(Nx.greater_equal(f, fs / 2), Nx.iota(f.shape), Nx.size(f) + 1)
  |> Nx.argmin()
  |> Nx.to_number()

spectrogram = z |> Nx.slice([0, 0], [Nx.size(t), max_f]) |> Nx.abs() |> Nx.pow(2)

filtered_spectrogram =
  z_filtered |> Nx.slice([0, 0], [Nx.size(t), max_f]) |> Nx.abs() |> Nx.pow(2)

# Reconstruct the time signal
data_out =
  z_filtered
  |> NxSignal.istft(stft_window, fft_length: window_length, scaling: :spectrum, sampling_rate: fs)
  |> Nx.as_type(data.type)
plot_data =
  for t_idx <- 0..(Nx.size(t) - 1),
      f_idx <- 0..max_f,
      Nx.to_number(f[[f_idx]]) <= 4000,
      reduce: %{"t" => [], "f" => [], "s" => [], "filtered_s" => []} do
    %{"t" => t_acc, "f" => f_acc, "s" => s_acc, "filtered_s" => filtered_s_acc} ->
      %{
        "t" => [Nx.to_number(t[[t_idx]]) | t_acc],
        "f" => [Float.round(Nx.to_number(f[[f_idx]]), 3) | f_acc],
        "s" => [Nx.to_number(spectrogram[[t_idx, f_idx]]) | s_acc],
        "filtered_s" => [Nx.to_number(filtered_spectrogram[[t_idx, f_idx]]) | filtered_s_acc]
      }
  end
defmodule Spectrogram do
  alias VegaLite, as: Vl

  def plot(title, dataset) do
    Vl.new(title: title, width: 500, height: 500)
    |> Vl.mark(:rect)
    |> Vl.data_from_values(dataset)
    |> Vl.encode_field(:x, "t",
      type: :quantitative,
      title: "Time (seconds)",
      axis: [tick_min_step: 0.1],
      grid: false
    )
    |> Vl.encode_field(:y, "f",
      type: :quantitative,
      sort: "-x",
      title: "Frequency (Hz)",
      axis: [tick_count: 25],
      grid: false
    )
    |> Vl.encode_field(:color, "s",
      aggregate: :max,
      type: :quantitative,
      scale: [scheme: "viridis"],
      legend: [title: "dBFS"]
    )
    |> Vl.config(view: [stroke: nil])
  end
end
Spectrogram.plot("Spectrogram", Map.take(plot_data, ["t", "f", "s"]))
Spectrogram.plot(
  "Filtered Spectrogram",
  Map.take(plot_data, ["t", "f"]) |> Map.put("s", plot_data["filtered_s"])
)
plot_data = %{
  y: Nx.to_flat_list(data_out[[slice]]),
  x: Nx.to_flat_list(Nx.divide(n, fs)[[slice]])
}
VegaLite.new(width: 600, height: 400, title: "Reconstructed Signal")
|> VegaLite.data_from_values(plot_data, only: ["x", "y"])
|> VegaLite.mark(:line)
|> VegaLite.encode_field(:x, "x", type: :quantitative)
|> VegaLite.encode_field(:y, "y", type: :quantitative)
As we can see, the same original slice is now a pure 220Hz sine wave, because we got rid of the higher frequency harmonic.


  

    Spectrogram Plotting

Mix.install([
  {:nx_signal, "~> 0.2"},
  {:vega_lite, "~> 0.1.4"},
  {:kino_vega_lite, "~> 0.1.1"}
])
Generating the audio data
# You can load an audio file here.  For this example,
# we're producing 3 seconds of 220Hz, 440Hz, 1kHz and 3kHz sine waves

fs = 44.1e3
t_max = 3

full_n = ceil(fs * t_max)
half_n = div(full_n, 2)

# samples/sec * sec = samples
n = Nx.iota({half_n})

sin = fn freq, n ->
  Nx.sin(Nx.multiply(2 * :math.pi() * freq / fs, n))
end

sin220 = sin.(220, n)
sin440 = sin.(440, n)
sin1000 = sin.(1000, n)
sin3000 = sin.(3000, n)

data = Nx.concatenate([Nx.add(sin440, sin1000), Nx.add(sin220, sin3000)])
n = Nx.iota({full_n})

d = %{data: Nx.to_flat_list(data[[1000..1250]]), n: Nx.to_flat_list(n[[1000..1250]])}
VegaLite.new(width: 600, height: 600, title: "Audio Sample")
|> VegaLite.data_from_values(d, only: ["n", "data"])
|> VegaLite.mark(:line)
|> VegaLite.encode_field(:x, "n", type: :ordinal)
|> VegaLite.encode_field(:y, "data", type: :quantitative)
defmodule Spectrogram do
  alias VegaLite, as: Vl

  def calculate_stft_and_plot_spectrogram(
        input,
        fs,
        window_duration_ms,
        plot_cutoff_frequency \\ 4000
      ) do
    n_window = ceil(fs * window_duration_ms)
    window = NxSignal.Windows.hann(n_window, is_periodic: true)
    {spectrogram, f, t, max_f} = stft(input, window, fs)

    max_f = Nx.to_number(max_f)
    spectrogram = Nx.slice(spectrogram, [0, 0], [Nx.size(t), max_f])
    f = Nx.slice(f, [0], [max_f])

    spectrogram
    |> to_plot_data(f, t, plot_cutoff_frequency)
    |> plot()
  end

  defp stft(input, window, fs) do
    {s, t, f} = NxSignal.stft(input, window, sampling_rate: fs, fft_length: 1024)

    max_f =
      Nx.select(Nx.greater_equal(f, fs / 2), Nx.iota(Nx.shape(f)), Nx.size(f) + 1)
      |> Nx.argmin()

    spectrogram = Nx.abs(s)
    spectrogram = Nx.multiply(20, Nx.divide(Nx.log(Nx.divide(spectrogram, Nx.reduce_max(spectrogram))), Nx.log(10)))

    {spectrogram, f, t, max_f}
  end

  defp to_plot_data(s, f, t, plot_cutoff_frequency) do
    for t_idx <- 0..(Nx.size(t) - 1),
        f_idx <- 0..(Nx.size(f) - 1),
        Nx.to_number(f[[f_idx]]) <= plot_cutoff_frequency,
        reduce: %{"t" => [], "f" => [], "s" => []} do
      %{"t" => t_acc, "f" => f_acc, "s" => s_acc} ->
        %{
          "t" => [Nx.to_number(t[[t_idx]]) | t_acc],
          "f" => [Float.round(Nx.to_number(f[[f_idx]]), 3) | f_acc],
          "s" => [Nx.to_number(s[[t_idx, f_idx]]) | s_acc]
        }
    end
  end

  defp plot(dataset) do
    Vl.new(title: "Spectrogram", width: 500, height: 500)
    |> Vl.mark(:rect)
    |> Vl.data_from_values(dataset)
    |> Vl.encode_field(:x, "t",
      type: :quantitative,
      title: "Time (seconds)",
      axis: [tick_min_step: 0.1],
      grid: false
    )
    |> Vl.encode_field(:y, "f",
      type: :quantitative,
      sort: "-x",
      title: "Frequency (Hz)",
      axis: [tick_count: 25],
      grid: false
    )
    |> Vl.encode_field(:color, "s",
      aggregate: :max,
      type: :quantitative,
      scale: [scheme: "viridis"],
      legend: [title: "dBFS"]
    )
    |> Vl.config(view: [stroke: nil])
  end
end
Spectrogram.calculate_stft_and_plot_spectrogram(data, fs, 50.0e-3)
Notice how the first half of the spectrogram looks cleaner than the second one. This is due to the window length, that also interferes in how we can observe both our time and frequency resolutions.
Below we can see what happens if we use different window durations (150ms, 100ms and 25ms respectively).
Spectrogram.calculate_stft_and_plot_spectrogram(data, fs, 150.0e-3)
Spectrogram.calculate_stft_and_plot_spectrogram(data, fs, 100.0e-3)
Spectrogram.calculate_stft_and_plot_spectrogram(data, fs, 25.0e-3)

        fft_frequencies(sampling_rate, opts \\ [])

      


        Computes the frequency bins for a FFT with given options.



    


    
      
        istft(data, window, opts)

      


        Computes the Inverse Short-Time Fourier Transform of a tensor.



    


    
      
        mel_filters(fft_length, mel_bins, sampling_rate, opts \\ [])

      


        Generates weights for converting an STFT representation into MEL-scale.



    


    
      
        stft(data, window, opts \\ [])

      


        Computes the Short-Time Fourier Transform of a tensor.



    


    
      
        stft_to_mel(z, sampling_rate, opts \\ [])

      


        Converts a given STFT time-frequency spectrum into a MEL-scale time-frequency spectrum.



    





  
    Functions: Windowing
  


    
      
        as_windowed(tensor, opts \\ [])

      


        Returns a tensor of K windows of length N



    


    
      
        overlap_and_add(tensor, opts \\ [])

      


        Performs the overlap-and-add algorithm over
an {..., M, N}-shaped tensor, where M is the number of
windows and N is the window size.

        czt(x, opts \\ [])

      


        Chirp Z-Transform.



    


    
      
        zoom_fft(x, f1, f2, opts \\ [])

      


        Zoom FFT: high-resolution DFT over a narrow frequency band.

Computes the frequency bins for a FFT with given options.
Arguments
	sampling_rate - Sampling frequency in Hz.

Options
	:fft_length - Number of FFT frequency bins.
	:type - Optional output type. Defaults to {:f, 32}
	:name - Optional axis name for the tensor. Defaults to :frequencies

Examples
iex> NxSignal.fft_frequencies(1.6e4, fft_length: 10)
#Nx.Tensor<
  f32[frequencies: 10]
  [0.0, 1.6e3, 3.2e3, 4.8e3, 6.4e3, 8e3, 9.6e3, 1.12e4, 1.28e4, 1.44e4]
>

Computes the Inverse Short-Time Fourier Transform of a tensor.
Returns a tensor of M time-domain frames of length fft_length.
See also: NxSignal.Windows, stft/3
Options
	:fft_length - the DFT length that will be passed to Nx.fft/2. Defaults to :power_of_two.
	:overlap_length - the number of samples for the overlap between frames.
Defaults to half the window size.
	:sampling_rate - the sampling rate $F_s$ in Hz. Defaults to 1000.
	:scaling - nil, :spectrum or :psd.	:spectrum - each frame is multiplied by $\sum_{i} window[i]$.
	nil - No scaling is applied.
	:psd - each frame is multiplied by $\sqrt{F\_s\sum_{i} window[i]^2}$.



Examples
In general, istft/3 takes in the same parameters and window as the stft/3 that generated the spectrum.
In the first example, we can notice that the reconstruction is mostly perfect, aside from the first sample.
This is because the Hann window only ensures perfect reconstruction in overlapping regions, so the edges
of the signal end up being distorted.
iex> t = Nx.tensor([10, 10, 1, 0, 10, 10, 2, 20])
iex> w = NxSignal.Windows.hann(4)
iex> opts = [sampling_rate: 1, fft_length: 4]
iex> {z, _time, _freqs} = NxSignal.stft(t, w, opts)
iex> result = NxSignal.istft(z, w, opts)
iex> Nx.as_type(result, Nx.type(t))
#Nx.Tensor<
  s32[8]
  [0, 10, 1, 0, 10, 10, 2, 20]
>
Different scaling options are available (see stft/3 for a more detailed explanation).
For perfect reconstruction, you want to use the same scaling as the STFT:
iex> t = Nx.tensor([10, 10, 1, 0, 10, 10, 2, 20])
iex> w = NxSignal.Windows.hann(4)
iex> opts = [scaling: :spectrum, sampling_rate: 1, fft_length: 4]
iex> {z, _time, _freqs} = NxSignal.stft(t, w, opts)
iex> result = NxSignal.istft(z, w, opts)
iex> Nx.as_type(result, Nx.type(t))
#Nx.Tensor<
  s32[8]
  [0, 10, 1, 0, 10, 10, 2, 20]
>

iex> t = Nx.tensor([10, 10, 1, 0, 10, 10, 2, 20], type: :f32)
iex> w = NxSignal.Windows.hann(4)
iex> opts = [scaling: :psd, sampling_rate: 1, fft_length: 4]
iex> {z, _time, _freqs} = NxSignal.stft(t, w, opts)
iex> result = NxSignal.istft(z, w, opts)
iex> Nx.as_type(result, Nx.type(t))
#Nx.Tensor<
  f32[8]
  [0.0, 10.0, 0.99999994, -2.1900146e-7, 10.0, 10.0, 2.0000002, 20.0]
>

Generates weights for converting an STFT representation into MEL-scale.
See also: stft/3, istft/3, stft_to_mel/3
Arguments
	fft_length - Number of FFT bins
	mel_bins - Number of target MEL bins
	sampling_rate - Sampling frequency in Hz

Options
	:max_mel - the pitch for the last MEL bin before log scaling. Defaults to 3016
	:mel_frequency_spacing - the distance in Hz between two MEL bins before log scaling. Defaults to 66.6
	:type - Target output type. Defaults to {:f, 32}

Examples
iex> NxSignal.mel_filters(10, 5, 8.0e3)
#Nx.Tensor<
  f32[mels: 5][frequencies: 10]
  [
    [0.0, 8.129208e-4, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0],
    [0.0, 9.972017e-4, 2.1870289e-4, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0],
    [0.0, 0.0, 9.510892e-4, 4.1505092e-4, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0],
    [0.0, 0.0, 0.0, 4.035892e-4, 5.276656e-4, 2.574124e-4, 0.0, 0.0, 0.0, 0.0],
    [0.0, 0.0, 0.0, 0.0, 7.329034e-5, 2.3422057e-4, 3.8295105e-4, 2.871204e-4, 1.9128979e-4, 9.545916e-5]
  ]
>

Computes the Short-Time Fourier Transform of a tensor.
Returns the complex spectrum Z, the time in seconds for
each frame and the frequency bins in Hz.
The STFT is parameterized through:
	$k$: length of the Discrete Fourier Transform (DFT)
	$N$: length of each frame
	$H$: hop (in samples) between frames (calculated as $H = N - \text{overlap\\_length}$)
	$M$: number of frames
	$x[n]$: the input time-domain signal
	$w[n]$: the window function to be applied to each frame

$$
DFT(x, w) := \sum_{n=0}^{N - 1} x[n]w[n]e^\frac{-2 \pi i k n}{N} \\\\
X[m, k] = DFT(x[mH..(mH + N - 1)], w)
$$
where $m$ assumes all values in the interval $[0, M - 1]$
See also: NxSignal.Windows, istft/3, stft_to_mel/3
Options
	:sampling_rate - the sampling frequency $F_s$ for the input in Hz. Defaults to 1000.
	:fft_length - the DFT length that will be passed to Nx.fft/2. Defaults to :power_of_two.
	:overlap_length - the number of samples for the overlap between frames.
Defaults to half the window size.
	:window_padding - :reflect, :zeros or nil. See as_windowed/3 for more details.
	:scaling - nil, :spectrum or :psd.	:spectrum - each frame is divided by $\sum_{i} window[i]$.
	nil - No scaling is applied.
	:psd - each frame is divided by $\sqrt{F\_s\sum_{i} window[i]^2}$.



Examples
iex> {z, t, f} = NxSignal.stft(Nx.iota({4}), NxSignal.Windows.rectangular(2), overlap_length: 1, fft_length: 2, sampling_rate: 400)
iex> z
#Nx.Tensor<
  c64[frames: 3][frequencies: 2]
  [
    [1.0+0.0i, -1.0+0.0i],
    [3.0+0.0i, -1.0+0.0i],
    [5.0+0.0i, -1.0+0.0i]
  ]
>
iex> t
#Nx.Tensor<
  f32[frames: 3]
  [0.0025, 0.005, 0.0075]
>
iex> f
#Nx.Tensor<
  f32[frequencies: 2]
  [0.0, 200.0]
>

Converts a given STFT time-frequency spectrum into a MEL-scale time-frequency spectrum.
See also: stft/3, istft/3, mel_filters/4
Arguments
	z - STFT spectrum
	sampling_rate - Sampling frequency in Hz

Options
	:fft_length - Number of FFT bins
	:mel_bins - Number of target MEL bins. Defaults to 128
	:type - Target output type. Defaults to {:f, 32}

Examples
iex> fft_length = 16
iex> sampling_rate = 8.0e3
iex> {z, _, _} = NxSignal.stft(Nx.iota({10}), NxSignal.Windows.hann(4), overlap_length: 2, fft_length: fft_length, sampling_rate: sampling_rate, window_padding: :reflect)
iex> Nx.axis_size(z, :frequencies)
16
iex> Nx.axis_size(z, :frames)
6
iex> NxSignal.stft_to_mel(z, sampling_rate, fft_length: fft_length, mel_bins: 4)
#Nx.Tensor<
  f32[frames: 6][mel: 4]
  [
    [0.29005307, 0.17422175, 0.18422472, 0.09807998],
    [0.6093881, 0.5647397, 0.43538243, 0.086352706],
    [0.75841033, 0.70850146, 0.5636921, 0.17911881],
    [0.8461772, 0.7952491, 0.64707625, 0.25204098],
    [0.9085489, 0.85726047, 0.70786566, 0.30867678],
    [0.9085489, 0.85726047, 0.70786566, 0.30867678]
  ]
>

Returns a tensor of K windows of length N
Options
	:window_length - the number of samples in a window
	:stride - The number of samples to skip between windows. Defaults to 1.
	:padding - Padding mode, can be :reflect or a valid padding as per Nx.pad/3 over the
input tensor's shape. Defaults to :valid. If :reflect or :same, the first window will be centered
at the start of the signal. The padding is applied for the whole input, rather than individual
windows. For :zeros, effectively each incomplete window will be zero-padded.

Examples
iex> NxSignal.as_windowed(Nx.tensor([0, 1, 2, 3, 4, 10, 11, 12]), window_length: 4)
#Nx.Tensor<
  s32[5][4]
  [
    [0, 1, 2, 3],
    [1, 2, 3, 4],
    [2, 3, 4, 10],
    [3, 4, 10, 11],
    [4, 10, 11, 12]
  ]
>

iex> NxSignal.as_windowed(Nx.tensor([0, 1, 2, 3, 4, 10, 11, 12]), window_length: 3)
#Nx.Tensor<
  s32[6][3]
  [
    [0, 1, 2],
    [1, 2, 3],
    [2, 3, 4],
    [3, 4, 10],
    [4, 10, 11],
    [10, 11, 12]
  ]
>

iex> NxSignal.as_windowed(Nx.tensor([0, 1, 2, 3, 4, 10, 11]), window_length: 2, stride: 2, padding: [{0, 3}])
#Nx.Tensor<
  s32[5][2]
  [
    [0, 1],
    [2, 3],
    [4, 10],
    [11, 0],
    [0, 0]
  ]
>

iex> t = Nx.iota({7});
iex> NxSignal.as_windowed(t, window_length: 6, padding: :reflect, stride: 1)
#Nx.Tensor<
  s32[8][6]
  [
    [3, 2, 1, 0, 1, 2],
    [2, 1, 0, 1, 2, 3],
    [1, 0, 1, 2, 3, 4],
    [0, 1, 2, 3, 4, 5],
    [1, 2, 3, 4, 5, 6],
    [2, 3, 4, 5, 6, 5],
    [3, 4, 5, 6, 5, 4],
    [4, 5, 6, 5, 4, 3]
  ]
>

iex> NxSignal.as_windowed(Nx.iota({10}), window_length: 6, padding: :reflect, stride: 2)
#Nx.Tensor<
  s32[6][6]
  [
    [3, 2, 1, 0, 1, 2],
    [1, 0, 1, 2, 3, 4],
    [1, 2, 3, 4, 5, 6],
    [3, 4, 5, 6, 7, 8],
    [5, 6, 7, 8, 9, 8],
    [7, 8, 9, 8, 7, 6]
  ]
>

  



    

  
    
      
    
    
      overlap_and_add(tensor, opts \\ [])



        
          
        

    

  


  

Performs the overlap-and-add algorithm over
an {..., M, N}-shaped tensor, where M is the number of
windows and N is the window size.
The tensor is zero-padded on the right so
the last window fully appears in the result.
Options
	:overlap_length - The number of overlapping samples between windows
	:type - output type for casting the accumulated result.
If not given, defaults to Nx.Type.to_complex/1 called on the input type.

Examples
iex> NxSignal.overlap_and_add(Nx.iota({3, 4}), overlap_length: 0)
#Nx.Tensor<
  s32[12]
  [0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11]
>

iex> NxSignal.overlap_and_add(Nx.iota({3, 4}), overlap_length: 3)
#Nx.Tensor<
  s32[6]
  [0, 5, 15, 18, 17, 11]
>

iex> t = Nx.tensor([[[[0, 1, 2, 3], [4, 5, 6, 7]]], [[[10, 11, 12, 13], [14, 15, 16, 17]]]]) |> Nx.vectorize(x: 2, y: 1)
iex> NxSignal.overlap_and_add(t, overlap_length: 3)
#Nx.Tensor<
  vectorized[x: 2][y: 1]
  s32[5]
  [
    [
      [0, 5, 7, 9, 7]
    ],
    [
      [10, 25, 27, 29, 17]
    ]
  ]
>

  


        

      

      
        Functions


        


    

  
    
      
    
    
      czt(x, opts \\ [])



        
          
        

    

  


  

Chirp Z-Transform.
Evaluates the z-transform of x on a spiral contour in the z-plane,
returning $M$ output points. Uses Bluestein's identity to express the
sum as a convolution, giving $O((N+M)\log(N+M))$ complexity.
$$
X[k] = \sum_{n=0}^{N-1} x[n] \, A^{-n} \, W^{nk}, \quad k = 0, 1, \ldots, M-1
$$
When $A = 1$, $W = e^{-j2\pi/M}$, and $M = N$, the result is identical
to the standard DFT.
See also: zoom_fft/4
Options
	:output_length - number of output points $M$. Defaults to Nx.size(x).
	:contour_ratio - contour ratio $W$ (complex scalar tensor).
Defaults to $e^{-j2\pi/M}$, which gives the DFT.
	:contour_start - contour starting point $A$ (complex scalar tensor).
Defaults to $1$.

Examples
iex> NxSignal.czt(Nx.tensor([1.0, 0.0, 0.0, 0.0]))
#Nx.Tensor<
  c64[4]
  [1.0-1.5893256e-8i, 0.99999994+0.0i, 1.0+1.5893256e-8i, 0.99999994+0.0i]
>

  



    

  
    
      
    
    
      zoom_fft(x, f1, f2, opts \\ [])



        
          
        

    

  


  

Zoom FFT: high-resolution DFT over a narrow frequency band.
Computes $M$ output samples of the DFT concentrated in the normalised
frequency range $[f_1, f_2]$. This is a thin wrapper around czt/2 that
sets:
$$
A = e^{j2\pi f_1}, \quad W = e^{-j2\pi(f_2 - f_1)/M}
$$
The output frequencies are $f_k = f_1 + k\,(f_2 - f_1)/M$ for $k = 0, \ldots, M-1$.
See also: czt/2
Arguments
	x  - input signal, shape {n}.
	f1 - lower bound of the frequency range (normalised, 0 to 1).
	f2 - upper bound of the frequency range (normalised, 0 to 1).

Options
	:output_length - number of output points $M$. Defaults to Nx.size(x).

Examples
iex> NxSignal.zoom_fft(Nx.tensor([1.0, 0.0, 0.0, 0.0]), 0.0, 1.0) |> Nx.real() |> Nx.round()
#Nx.Tensor<
  f32[4]
  [1.0, 1.0, 1.0, 1.0]
>

  


        

      


  

    
NxSignal.Convolution 
    



      
Convolution functions through various methods.
Follows the scipy.signal conventions.

      


      
        Summary


  
    Functions
  


    
      
        convolve(in1, in2, opts \\ [])

      


        Computes the convolution of two tensors.



    


    
      
        correlate(in1, in2, opts \\ [])

      


        Computes the correlation of two tensors.



    


    
      
        fftconvolve(in1, in2, opts \\ [])

      


        Computes the convolution of two tensors via FFT.



    





      


      
        Functions


        


    

  
    
      
    
    
      convolve(in1, in2, opts \\ [])



        
          
        

    

  


  

Computes the convolution of two tensors.
Given $f[n]$ of length $N$ and $k[n]$ of length ${K}$, we define the convolution $g[n] = (f * k)[n]$ by
$$
g[n] = (f * k)[n] = \sum_{m=0}^{K-1} f[n-m]k[m],
$$
where $f[n]$ and $k[n]$ are assumed to be zero outside of their definition boundaries.
Options
	:method - One of :fft or :direct. Defaults to :direct.
	:mode - One of :full, :valid, or :same. Defaults to :full.	:full returns all $N + K - 1$ samples.
	:same returns the center $N$ samples.
	:valid returns the center $N - K + 1$ samples.



Examples
  iex> NxSignal.Convolution.convolve(Nx.tensor([1,2,3]), Nx.tensor([3,4,5]))
  #Nx.Tensor<
f32[5]
[3.0, 10.0, 22.0, 22.0, 15.0]


  



    

  
    
      
    
    
      correlate(in1, in2, opts \\ [])



        
          
        

    

  


  

Computes the correlation of two tensors.
Given $f[n]$ of length $N$ and $k[n]$ of length ${K}$, we define the correlation $g[n] = (f \star k)[n]$ by
$$
g[n] = (f \star k)[n] = \\sum_{m = 0}^{K - 1}f[n - m]k^\*[K - 1 - m]
$$
where $k^\*[n]$ is the complex conjugate of $k[n]$.
Options
	:method - One of :fft or :direct. Defaults to :direct.
	:mode - One of :full, :valid, or :same. Defaults to :full.	:full returns all $N + K - 1$ samples.
	:same returns the center $N$ samples.
	:valid returns the center $N - K + 1$ samples.



Examples
  iex> NxSignal.Convolution.correlate(Nx.tensor([1,2,3]), Nx.tensor([3,4,5]))
  #Nx.Tensor<
f32[5]
[5.0, 14.0, 26.0, 18.0, 9.0]


  



    

  
    
      
    
    
      fftconvolve(in1, in2, opts \\ [])



        
          
        

    

  


  

Computes the convolution of two tensors via FFT.
Given signals $f[n]$, with length $N$, and $k[n]$, with length $K$, we define the convolution $g[n] = (f * k)[n]$ by
$$
g[n] = \text{FFT}^{-1}(\text{FFT}(f[n]) \cdot \text{FFT}(k[n]))
$$
where $f[n]$ and $k[n]$ have their DFTs calculated with $N + K - 1$ samples.
The output is sliced in accordance to the mode option, as described below.
Options
	:mode - One of :full, :valid, or :same. Defaults to :full.	:full returns all $N + K - 1$ samples.
	:same returns the center $N$ samples.
	:valid returns the center $N - K + 1$ samples.



Examples
  iex> NxSignal.Convolution.fftconvolve(Nx.tensor([1,2,3]), Nx.tensor([3,4,5]))
  #Nx.Tensor<
f32[5]
[3.0000007, 10.0, 22.0, 22.0, 15.0]


  


        

      


  

    
NxSignal.Filters 
    



      
Common filter functions.

      


      
        Summary


  
    Functions: Filters
  


    
      
        firwin(num_taps, cutoff, opts \\ [])

      


        FIR filter design using the window method.



    


    
      
        median(t, opts)

      


        Performs a median filter on a tensor.



    


    
      
        wiener(t, opts \\ [])

      


        Applies a Wiener filter to the given Nx tensor.



    





      


      
        Functions: Filters


        


    

  
    
      
    
    
      firwin(num_taps, cutoff, opts \\ [])



        
          
        

    

  


  

FIR filter design using the window method.
Computes the coefficients of a finite impulse response (FIR) filter.
The filter has linear phase (Type I for odd num_taps, Type II for even).
Type II filters have a zero at Nyquist, so a filter requiring gain there
must use an odd number of taps.
Arguments
	num_taps - number of filter coefficients (filter order + 1).
	cutoff - list of cutoff frequencies in the same units as sampling_rate.

Options
	:window - window function to apply. One of :hamming, :hann,
:blackman, :bartlett, :rectangular, or {:kaiser, beta}.
Defaults to :hamming.
	:pass_zero - if true, the DC gain is 1 (lowpass or bandstop);
if false, the DC gain is 0 (highpass or bandpass). Defaults to true.
	:scale - if true, normalise the coefficients so the frequency
response is exactly 1 at a reference frequency. Defaults to true.
	:sampling_rate - the sampling rate in Hz; cutoff is given in the
same units. Defaults to 2.0 so cutoffs are already normalised to
[0, 1] where 1 equals Nyquist.
	:type - output tensor type. Defaults to {:f, 32}.

Examples
iex> coeffs = NxSignal.Filters.firwin(5, [0.3], window: :hamming, sampling_rate: 2.0)
iex> Nx.shape(coeffs)
{5}

  



  
    
      
    
    
      median(t, opts)



        
          
        

    

  


  

Performs a median filter on a tensor.
Options
	:kernel_shape - the shape of the sliding window.
It must be compatible with the shape of the tensor.


  



    

  
    
      
    
    
      wiener(t, opts \\ [])



        
          
        

    

  


  

Applies a Wiener filter to the given Nx tensor.
Options
* `:kernel_size` - filter size given either a number or a tuple. 
  If a number is given, a kernel with the given size, and same number of axes 
  as the input tensor will be used. Defaults to `3`.
* `:noise` - noise power, given as a scalar. This will be estimated based on the input tensor if `nil`. Defaults to `nil`.
Examples
iex> t = Nx.tensor([[1.0, 2.0, 3.0], [4.0, 5.0, 6.0], [7.0, 8.0, 9.0]])
iex> NxSignal.Filters.wiener(t, kernel_size: {2, 2}, noise: 10)
#Nx.Tensor<
  f32[3][3]
  [
    [0.25, 0.75, 1.25],
    [1.25, 3.0, 4.0],
    [2.75, 6.0, 7.0]
  ]
>

  


        

      


  

    
NxSignal.PeakFinding 
    



      
Peak finding algorithms.

      


      
        Summary


  
    Functions
  


    
      
        argrelextrema(data, comparator_fn, opts \\ [])

      


        Finds a relative extrema along the selected :axis.



    


    
      
        argrelmax(data, opts \\ [])

      


        Finds a relative maximum along the selected :axis.



    


    
      
        argrelmin(data, opts \\ [])

      


        Finds a relative minimum along the selected :axis.



    





      


      
        Functions


        


    

  
    
      
    
    
      argrelextrema(data, comparator_fn, opts \\ [])



        
          
        

    

  


  

Finds a relative extrema along the selected :axis.
A relative extremum is defined by the given comparator_fn
function of arity 2 function that returns a boolean tensor.
This is the function upon which &argrelmax/2 and &argrelmin/2
are implemented.
Returns a map in the following format:
%{
  indices: #Nx.Tensor<...>,
  valid_indices: #Nx.Tensor<...>
}
	:indices - the {n, rank} tensor of indices.
Contains -1 as a placeholder for invalid indices.

	:valid_indices - the number of valid indices that lead the tensor.


Options
	:axis - the axis along which to do comparisons. Defaults to 0.
	:order - the number of neighbor samples considered for the
comparison in each direction. Defaults to 1.

Examples
First, do read the examples on argrelmax/2 keeping in mind that
it is equivalent to argrelextrema(&1, &Nx.greater/2, &2), as well
as argrelmin/2 which is equivalent to argrelextrema(&1, &Nx.less/2, &2).
Having that in mind, we will expand on those concepts by using a custom function.
For instance, we can change the definition of a relative maximum to one where
a number is a relative maximum if it is greater than or equal to the double of its
neighbors, as follows:
iex> comparator = fn x, y -> Nx.greater_equal(x, Nx.multiply(y, 2)) end
iex> x = Nx.tensor([0, 1, 3, 2, 0, 1, 0, 0, 0, 2, 1])
iex> result = NxSignal.PeakFinding.argrelextrema(x, comparator)
iex> result.valid_indices
#Nx.Tensor<
  u32
  3
>
iex> result.indices[0..2]
#Nx.Tensor<
  s32[3][1]
  [
    [5],
    [7],
    [9]
  ]
>
Same applies for finding local minima. In the next example, we
find all local minima (i.e. &Nx.less/2) that are
different to the global minimum.
iex> x = Nx.tensor([0, 1, 0, 2, 1, 3, 0, 1])
iex> global_minimum = Nx.reduce_min(x)
iex> comparator = fn x, y ->
...> x_not_global = Nx.not_equal(x, global_minimum)
...> y_not_global = Nx.not_equal(y, global_minimum)
...> both_not_global = Nx.logical_and(x_not_global, y_not_global)
...> Nx.logical_and(Nx.less(x, y), both_not_global)
...> end
iex> result = NxSignal.PeakFinding.argrelextrema(x, comparator)
iex> result.valid_indices
#Nx.Tensor<
  u32
  1
>
iex> result.indices[0..0]
#Nx.Tensor<
  s32[1][1]
  [
    [4]
  ]
>

  



    

  
    
      
    
    
      argrelmax(data, opts \\ [])



        
          
        

    

  


  

Finds a relative maximum along the selected :axis.
A relative maximum is defined by the element being greater
than its neighbors along the axis :axis.
Returns a map in the following format:
%{
  indices: #Nx.Tensor<...>,
  valid_indices: #Nx.Tensor<...>
}
	:indices - the {n, rank} tensor of indices.
Contains -1 as a placeholder for invalid indices.

	:valid_indices - the number of valid indices that lead the tensor.


Options
	:axis - the axis along which to do comparisons. Defaults to 0.
	:order - the number of neighbor samples considered for the
comparison in each direction. Defaults to 1.

Examples
iex> x = Nx.tensor([2, 1, 2, 3, 2, 0, 1, 0])
iex> %{indices: indices, valid_indices: valid_indices} = NxSignal.PeakFinding.argrelmax(x)
iex> valid_indices
#Nx.Tensor<
  u32
  2
>
iex> indices
#Nx.Tensor<
  s32[8][1]
  [
    [3],
    [6],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1]
  ]
>
iex> Nx.slice_along_axis(indices, 0, Nx.to_number(valid_indices), axis: 0)
#Nx.Tensor<
  s32[2][1]
  [
    [3],
    [6]
  ]
>
For the same tensor in the previous example, we can use :order to check if
the relative maxima are extrema in a wider neighborhood.
iex> x = Nx.tensor([2, 1, 2, 3, 2, 0, 1, 0])
iex> %{indices: indices, valid_indices: valid_indices} = NxSignal.PeakFinding.argrelmax(x, order: 3)
iex> valid_indices
#Nx.Tensor<
  u32
  1
>
iex> indices
#Nx.Tensor<
  s32[8][1]
  [
    [3],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1]
  ]
>
iex> Nx.slice_along_axis(indices, 0, Nx.to_number(valid_indices), axis: 0)
#Nx.Tensor<
  s32[1][1]
  [
    [3]
  ]
>
We can also apply this function to tensors with a larger rank:
iex> x = Nx.tensor([[1, 2, 1, 2], [6, 2, 0, 0], [5, 3, 4, 4]])
iex> %{indices: indices, valid_indices: valid_indices} = NxSignal.PeakFinding.argrelmax(x)
iex> valid_indices
#Nx.Tensor<
  u32
  1
>
iex> indices[0]
#Nx.Tensor<
  s32[2]
  [1, 0]
>
iex> %{indices: indices} = NxSignal.PeakFinding.argrelmax(x, axis: 1)
iex> valid_indices
#Nx.Tensor<
  u32
  1
>
iex> indices[0]
#Nx.Tensor<
  s32[2]
  [0, 1]
>

  



    

  
    
      
    
    
      argrelmin(data, opts \\ [])



        
          
        

    

  


  

Finds a relative minimum along the selected :axis.
A relative minimum is defined by the element being greater
than its neighbors along the axis :axis.
Returns a map in the following format:
%{
  indices: #Nx.Tensor<...>,
  valid_indices: #Nx.Tensor<...>
}
	:indices - the {n, rank} tensor of indices.
Contains -1 as a placeholder for invalid indices.

	:valid_indices - the number of valid indices that lead the tensor.


Options
	:axis - the axis along which to do comparisons. Defaults to 0.
	:order - the number of neighbor samples considered for the
comparison in each direction. Defaults to 1.

Examples
iex> x = Nx.tensor([2, 1, 2, 3, 2, 0, 1, 0])
iex> %{indices: indices, valid_indices: valid_indices} = NxSignal.PeakFinding.argrelmin(x)
iex> valid_indices
#Nx.Tensor<
  u32
  2
>
iex> indices
#Nx.Tensor<
  s32[8][1]
  [
    [1],
    [5],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1]
  ]
>
iex> Nx.slice_along_axis(indices, 0, Nx.to_number(valid_indices), axis: 0)
#Nx.Tensor<
  s32[2][1]
  [
    [1],
    [5]
  ]
>
For the same tensor in the previous example, we can use :order to check if
the relative maxima are extrema in a wider neighborhood.
iex> x = Nx.tensor([2, 1, 2, 3, 2, 0, 1, 0])
iex> %{indices: indices, valid_indices: valid_indices} = NxSignal.PeakFinding.argrelmin(x, order: 3)
iex> valid_indices
#Nx.Tensor<
  u32
  1
>
iex> indices
#Nx.Tensor<
  s32[8][1]
  [
    [1],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1],
    [-1]
  ]
>
iex> Nx.slice_along_axis(indices, 0, Nx.to_number(valid_indices), axis: 0)
#Nx.Tensor<
  s32[1][1]
  [
    [1]
  ]
>
We can also apply this function to tensors with a larger rank:
iex> x = Nx.tensor([[1, 2, 1, 2], [6, 2, 0, 0], [5, 3, 4, 4]])
iex> %{indices: indices, valid_indices: valid_indices} = NxSignal.PeakFinding.argrelmin(x)
iex> valid_indices
#Nx.Tensor<
  u32
  2
>
iex> indices[0..1]
#Nx.Tensor<
  s32[2][2]
  [
    [1, 2],
    [1, 3]
  ]
>
iex> %{indices: indices} = NxSignal.PeakFinding.argrelmin(x, axis: 1)
iex> valid_indices
#Nx.Tensor<
  u32
  2
>
iex> indices[0..1]
#Nx.Tensor<
  s32[2][2]
  [
    [0, 2],
    [2, 1]
  ]
>

  


        

      


  

    
NxSignal.Waveforms 
    



      
Functions that calculate waveforms given a time tensor.

      


      
        Summary


  
    Functions: Waveforms
  


    
      
        chirp(t, f0, t1, f1, opts \\ [])

      


        Chirp function.



    


    
      
        gaussian_pulse(t, opts \\ [])

      


        Gaussian modulated sinusoid.



    


    
      
        polynomial_sweep(t, coefs, opts \\ [])

      


        Frequency-swept cosine generator, with a time-dependent frequency.



    


    
      
        sawtooth(t, opts \\ [])

      


        Periodic sawtooth or triangular waveform.



    


    
      
        sinc(t)

      


        Calculates the normalized sinc function $sinc(t) = \frac{sin(\pi t)}{\pi t}$



    


    
      
        square(t, opts \\ [])

      


        A periodic square wave with period $2\pi$.



    


    
      
        unit_impulse(shape, opts \\ [])

      


        Discrete delta function or unit basis vector.



    





      


      
        Functions: Waveforms


        


    

  
    
      
    
    
      chirp(t, f0, t1, f1, opts \\ [])



        
          
        

    

  


  

Chirp function.
Starts at t with frequency f0 and ends at t1 with
frequency f1.
Options
	:phi - phase shift for the chirp.
	:vertex_zero - determines the position of the parabolic vertex
for when method: :quadratic. Defaults to true.
	:method - One of various frequency interpolation methods:	:linear - linear interpolation.
	:quadratic - parabolic interpolation with vertex at t1 or t0,
depending if vertex_zero: false or vertex_zero: true respectively.
	:hyperbolic - hyperbolic interpolation.
	:logarithmic - logarithmic (also known as geometric or exponential)
interpolation. f0 and f1 must be non-zero and have the same sign.



Examples
iex> t = Nx.linspace(0, 10, n: 5)
iex> NxSignal.Waveforms.chirp(t, 10, 10, 1, method: :linear)
#Nx.Tensor<
  f32[5]
  [1.0, 0.3826847, 3.7950333e-6, -0.38268313, 1.0]
>
iex> NxSignal.Waveforms.chirp(t, 10, 10, 1, method: :quadratic)
#Nx.Tensor<
  f32[5]
  [1.0, -0.98078334, -9.958475e-8, -0.5555804, 1.0]
>
iex> NxSignal.Waveforms.chirp(t, 10, 10, 1, method: :quadratic, vertex_zero: false)
#Nx.Tensor<
  f32[5]
  [1.0, 0.5555851, -7.4904815e-6, 0.98078454, 1.0]
>
iex> NxSignal.Waveforms.chirp(t, 10, 10, 1, method: :hyperbolic)
#Nx.Tensor<
  f32[5]
  [1.0, 0.8229323, 0.93353605, 0.013466472, -0.863033]
>
iex> NxSignal.Waveforms.chirp(t, 10, 10, 1, method: :logarithmic)
#Nx.Tensor<
  f32[5]
  [1.0, 0.9989554, -0.33371755, -0.27006125, 0.85589826]
>

  



    

  
    
      
    
    
      gaussian_pulse(t, opts \\ [])



        
          
        

    

  


  

Gaussian modulated sinusoid.
The returned value follows the formula:
$$
f(t) = e^{-at^2}(cos(2 \pi f_c t) + isin(2 \pi f_c t))
$$
Where the exponential envelope is returned as envelope,
and the real and imaginary parts of $f(t)$ are returned as
in_phase and quadrature in the output map.
Note that in_phase and quadrature are are equivalent to
$\operatorname{Re} \lbrace f(t) \rbrace$ and $\operatorname{Im} \lbrace f(t) \rbrace$ respectively.
Examples
iex> t = Nx.linspace(0, 1, n: 4)
iex> pulse = NxSignal.Waveforms.gaussian_pulse(t, center_frequency: 4)
iex> pulse.envelope
#Nx.Tensor<
  f32[4]
  [1.0, 0.20443118, 0.0017465799, 6.2362665e-7]
>
iex> pulse.in_phase
#Nx.Tensor<
  f32[4]
  [1.0, -0.102215625, -8.732892e-4, 6.2362665e-7]
>
iex> pulse.quadrature
#Nx.Tensor<
  f32[4]
  [0.0, 0.17704256, -0.001512583, 4.361534e-13]
>

iex> t = Nx.linspace(0, 1, n: 4)
iex> pulse = NxSignal.Waveforms.gaussian_pulse(t, center_frequency: 4, bandwidth: 0.25)
iex> pulse.envelope
#Nx.Tensor<
  f32[4]
  [1.0, 0.67241406, 0.20443118, 0.028101608]
>
iex> pulse.in_phase
#Nx.Tensor<
  f32[4]
  [1.0, -0.33620715, -0.102215506, 0.028101608]
>
iex> pulse.quadrature
#Nx.Tensor<
  f32[4]
  [0.0, 0.58232754, -0.17704263, 1.9653765e-8]
>

  



    

  
    
      
    
    
      polynomial_sweep(t, coefs, opts \\ [])



        
          
        

    

  


  

Frequency-swept cosine generator, with a time-dependent frequency.
This function generates a sinusoidal function whose instantaneous
frequency varies with time. The frequency at time t is given by
the polynomial specified by the coefficients contained in coefs.
See also: chirp/5
Options
	:phi - phase shift to be applied before calculating the Nx.cos
for the output. Defaults to 0.
	:phi_unit - determines if :phi is given in :radians or :degrees.
Defaults to :radians.

Examples
iex> t = Nx.linspace(0, 10, n: 5)
iex> NxSignal.Waveforms.polynomial_sweep(t, Nx.tensor([2, 0, 1]))
#Nx.Tensor<
  f32[5]
  [1.0, 0.8660273, -0.5000064, 1.7942519e-5, -0.4999892]
>
iex> NxSignal.Waveforms.polynomial_sweep(t, Nx.tensor([2, 0, 1]), phi: :math.pi() / 2)
#Nx.Tensor<
  f32[5]
  [-4.371139e-8, 0.49999946, -0.8660195, 1.0, 0.86603385]
>
iex> NxSignal.Waveforms.polynomial_sweep(t, Nx.tensor([1, 0]))
#Nx.Tensor<
  f32[5]
  [1.0, 0.70710653, -1.0, 0.7071085, 1.0]
>
iex> NxSignal.Waveforms.polynomial_sweep(t, Nx.tensor([1, 0]), phi: 180, phi_unit: :degrees)
#Nx.Tensor<
  f32[5]
  [-1.0, -0.70710695, 1.0, -0.70711297, -1.0]
>

Periodic sawtooth or triangular waveform.
The wave as a period of $2\pi$, rising from -1 to 1
in the interval $[0, 2\pi\cdot\text{width}]$ and dropping from
1 to -1 in the interval $[2\pi \cdot \text{width}, 2\pi]$.
Options
	:width - the width of the sawtooth. Must be a number
between 0 and 1 (both inclusive). Defaults to 1.

Examples
A 5Hz waveform sampled at 500Hz for 1 second can be defined as:
t = Nx.linspace(0, 1, n: 500)
n = Nx.multiply(2 * :math.pi() * 5, t)
wave = NxSignal.Waveforms.sawtooth(n)

Calculates the normalized sinc function $sinc(t) = \frac{sin(\pi t)}{\pi t}$
Examples
iex> NxSignal.Waveforms.sinc(Nx.tensor([0, 0.25, 1]))
#Nx.Tensor<
  f32[3]
  [1.0, 0.9003163, -2.7827534e-8]
>

A periodic square wave with period $2\pi$.
Evaluates to 1 in the interval $[0, 2\pi\text{duty}]$
and -1 in the interval $[2\pi\text{duty}, 2\pi]$.
Options
	:duty - a number or tensor representing the duty cycle.
If a tensor is given, the waveform changes over time, and it
must have the same length as the t input. Defaults to 0.5.

Examples
iex> t = Nx.iota({10}) |> Nx.multiply(:math.pi() * 2 / 10)
iex> NxSignal.Waveforms.square(t, duty: 0.1)
#Nx.Tensor<
  s32[10]
  [1, -1, -1, -1, -1, -1, -1, -1, -1, -1]
>
iex> NxSignal.Waveforms.square(t, duty: 0.5)
#Nx.Tensor<
  s32[10]
  [1, 1, 1, 1, 1, -1, -1, -1, -1, -1]
>
iex> NxSignal.Waveforms.square(t, duty: 1)
#Nx.Tensor<
  s32[10]
  [1, 1, 1, 1, 1, 1, 1, 1, 1, 1]
>

iex> t = Nx.iota({10}) |> Nx.multiply(:math.pi() * 2 / 10)
iex> duty = Nx.tensor([0.1, 0, 0.3, 0, 0.5, 0, 0.7, 0, 0.9, 0])
iex> NxSignal.Waveforms.square(t, duty: duty)
#Nx.Tensor<
  s32[10]
  [1, -1, 1, -1, 1, -1, 1, -1, 1, -1]
>

Discrete delta function or unit basis vector.
Options
	:index - one of number, numerical tensor
with length equal to the rank of the given
shape, or :midpoint. index: :midpoint,
is a shortcut for inserting the impulse
at the index which corresponds to half of
each dimension. Defaults to 0.

	:type - datatype for the output. Defaults to :f32.


Examples
iex> NxSignal.Waveforms.unit_impulse({2})
#Nx.Tensor<
  f32[2]
  [1.0, 0.0]
>

iex> NxSignal.Waveforms.unit_impulse({3, 5}, type: :s32, index: :midpoint)
#Nx.Tensor<
  s32[3][5]
  [
    [0, 0, 0, 0, 0],
    [0, 0, 1, 0, 0],
    [0, 0, 0, 0, 0]
  ]
>

iex> NxSignal.Waveforms.unit_impulse({3, 5}, index: Nx.tensor([[2, 3]]), type: :s32)
#Nx.Tensor<
  s32[3][5]
  [
    [0, 0, 0, 0, 0],
    [0, 0, 0, 0, 0],
    [0, 0, 0, 1, 0]
  ]
>

        Bartlett triangular window.

        Blackman window.

        Hamming window.

        Hann window.

        Creates a Kaiser window of size window_length.

        Rectangular window.

        Triangular window.



    





      


      
        Functions: Windowing


        


    

  
    
      
    
    
      bartlett(n, opts \\ [])



        
          
        

    

  


  

Bartlett triangular window.
See also: triangular/1
Options
	:type - the output type for the window. Defaults to {:f, 32}
	:name - the axis name. Defaults to nil

Examples
iex> NxSignal.Windows.bartlett(3)
#Nx.Tensor<
  f32[3]
  [0.0, 0.6666667, 0.6666666]
>

Blackman window.
Options
	:is_periodic - If true, produces a periodic window,
 otherwise produces a symmetric window. Defaults to true
	:type - the output type for the window. Defaults to {:f, 32}
	:name - the axis name. Defaults to nil

Examples
iex> NxSignal.Windows.blackman(5, is_periodic: false)
#Nx.Tensor<
  f32[5]
  [-1.4901161e-8, 0.34000003, 0.99999994, 0.34000003, -1.4901161e-8]
>

iex> NxSignal.Windows.blackman(5, is_periodic: true)
#Nx.Tensor<
  f32[5]
  [-1.4901161e-8, 0.20077012, 0.84922993, 0.84922993, 0.20077012]
>

iex> NxSignal.Windows.blackman(6, is_periodic: true, type: {:f, 32})
#Nx.Tensor<
  f32[6]
  [-1.4901161e-8, 0.13, 0.63, 0.99999994, 0.63, 0.13]
>

Hamming window.
Options
	:is_periodic - If true, produces a periodic window,
 otherwise produces a symmetric window. Defaults to true
	:type - the output type for the window. Defaults to {:f, 32}
	:name - the axis name. Defaults to nil

Examples
iex> NxSignal.Windows.hamming(5, is_periodic: true)
#Nx.Tensor<
  f32[5]
  [0.08000001, 0.3978522, 0.9121479, 0.9121479, 0.3978522]
>
iex> NxSignal.Windows.hamming(5, is_periodic: false)
#Nx.Tensor<
  f32[5]
  [0.08000001, 0.54, 1.0, 0.54, 0.08000001]
>

Hann window.
Options
	:is_periodic - If true, produces a periodic window,
 otherwise produces a symmetric window. Defaults to true
	:type - the output type for the window. Defaults to {:f, 32}
	:name - the axis name. Defaults to nil

Examples
iex> NxSignal.Windows.hann(5, is_periodic: false)
#Nx.Tensor<
  f32[5]
  [0.0, 0.5, 1.0, 0.5, 0.0]
>
iex> NxSignal.Windows.hann(5, is_periodic: true)
#Nx.Tensor<
  f32[5]
  [0.0, 0.34549153, 0.90450853, 0.90450853, 0.34549153]
>

Creates a Kaiser window of size window_length.
The Kaiser window is a taper formed by using a Bessel function.
Options
	:is_periodic - If true, produces a periodic window,
 otherwise produces a symmetric window. Defaults to true
	:type - the output type for the window. Defaults to {:f, 32}
	:beta - Shape parameter for the window. As beta increases, the window becomes more focused in frequency domain. Defaults to 12.0.
	:eps - Epsilon value to avoid division by zero. Defaults to 1.0e-7.
	:axis_name - the axis name. Defaults to nil

Examples
iex> NxSignal.Windows.kaiser(4, beta: 12.0, is_periodic: true)
#Nx.Tensor<
  f32[4]
  [5.277619e-5, 0.21566667, 1.0, 0.21566667]
>

iex> NxSignal.Windows.kaiser(5, beta: 12.0, is_periodic: true)
#Nx.Tensor<
  f32[5]
  [5.277619e-5, 0.10171464, 0.792937, 0.792937, 0.10171464]
>

iex> NxSignal.Windows.kaiser(4, beta: 12.0, is_periodic: false)
#Nx.Tensor<
  f32[4]
  [5.277619e-5, 0.5188395, 0.5188395, 5.277619e-5]
>

Rectangular window.
Useful for when no window function should be applied.
Options
	:type - the output type. Defaults to s64

Examples
iex> NxSignal.Windows.rectangular(5)
#Nx.Tensor<
  s64[5]
  [1, 1, 1, 1, 1]
>

iex> NxSignal.Windows.rectangular(5, type: :f32)
#Nx.Tensor<
  f32[5]
  [1.0, 1.0, 1.0, 1.0, 1.0]
>

Triangular window.
See also: bartlett/1
Options
	:n - The window length. Mandatory option.
	:type - the output type for the window. Defaults to {:f, 32}
	:name - the axis name. Defaults to nil

Examples
iex> NxSignal.Windows.triangular(3)
#Nx.Tensor<
  f32[3]
  [0.5, 1.0, 0.5]
>

  


        

      


  OEBPS/dist/epub-4WIP524F.js
(()=>{var s=document.querySelector.bind(document),o=document.querySelectorAll.bind(document);function r(e){document.readyState!=="loading"?e():document.addEventListener("DOMContentLoaded",e)}var l="hll";window.addEventListener("exdoc:loaded",t);function t(){o("[data-group-id]").forEach(e=>{e.addEventListener("mouseenter",i),e.addEventListener("mouseleave",i)})}function i(e){let n=e.currentTarget,a=e.type==="mouseenter",c=n.getAttribute("data-group-id");n.parentElement.querySelectorAll(`[data-group-id="${c}"]`).forEach(u=>{u.classList.toggle(l,a)})}r(()=>{t()});})();




